2.6 多光源 multiple lights
在之前的教程中,我们深入学习了OpenGL中的光照技术,包括Phong着色、材质、光照贴图以及各光源类型。本教程将综合运用所学知识,创建一个包含6各活动光源的完整光照场景。我们将模拟太阳般的定向光源,在场景中分散布置4个点光源,并添加一支手电筒。
为在场景中使用多光源,需将光照计算封装为GLSL函数。这是因为当涉及多种光源时,每种光源又需要不同计算方式,若直接在主函数中处理,代码很快会变得难以理解。若将所有计算集中在主函数中处理,代码将迅速变得难以理解。
GLSL中的函数与C语言函数类似,包含函数名和返回类型。但需注意:若函数在主函数之前未被声明,必须在代码文件顶部声明函数原型。我们将为每种光元类型创建独立函数:定向光、点光源和聚光灯。
场景中使用多光源时通常采用以下方案:我们有一个代表片段输出颜色的单一颜色向量。对于每个光源,其对片段的贡献颜色会被添加到该片段的输出颜色向量中。因此场景中的每个光源都会计算其对前述片段的独立影响,并共同构成最终输出颜色。其通用结构如下所示:
out vec4 FragColor;
void main()
{
// define an output color value
vec3 output = vec3(0.0);
// add the directional light's contribution to the output
output += someFunctionToCalculateDirectionalLight();
// do the same for all point lights
for(int i = 0; i < nr_of_point_lights; i++)
output += someFunctionToCalculatePointLight();
// and add others lights as well (like spotlights)
output += someFunctionToCalculateSpotLight();
FragColor = vec4(output, 1.0);
}
实际代码可能因实际情况而异,但基本结构保持不变。我们定义了多个函数,用于计算每个光源的影响,并将计算出的颜色添加到输出颜色向量中。例如当两个光源靠近光片时,它们的综合贡献会使光片比仅受单一光源照射时更明亮。
2.6.1 定向光 Directional light
我们要做的是在片段着色器中定义一个函数,用于计算定向光源对对应片段的贡献:该函数接收若干参数,并返回计算出的定向光照颜色。
首先需设定定向光源所需的最小变量集。可将这些变量存储在名为DirLight的结构体中,并将其定义为统一变量。所需变量应与前文教程中的内容一致:
struct DirLight {
vec3 direction;
vec3 ambient;
vec3 diffuse;
vec3 specular;
};
uniform DirLight dirLight;
随后可将dirLight统一变量传递给以下原型的函数:
vec3 CalcDirLight(DirLight light, vec3 normal, vec3 viewDir);
与C和C++类似,若要在主函数内部调用某个函数,该函数必须在调用行号之前完成定义。本例中我们更倾向于在主函数下方定义函数,因此无需满足此要求。故我们像C语言那样,在主函数上方声明函数原型。
可见该函数需要一个DirLight结构体及其计算所需的两个向量。若您已完成前一教程,此函数内容应不难理解:
vec3 CalcDirLight(DirLight light, vec3 normal, vec3 viewDir)
{
vec3 lightDir = normalize(-light.direction);
// diffuse shading
float diff = max(dot(normal, lightDir), 0.0);
// specular shading
vec3 reflectDir = reflect(-lightDir, normal);
float spec = pow(max(dot(viewDir, reflectDir), 0.0), material.shininess);
// combine results
vec3 ambient = light.ambient * vec3(texture(material.diffuse, TexCoords));
vec3 diffuse = light.diffuse * diff * vec3(texture(material.diffuse, TexCoords));
vec3 specular = light.specular * spec * vec3(texture(material.specular, TexCoords));
return (ambient + diffuse + specular);
}
我们基本复制了前一教程的代码,并利用作为函数参数传递的向量计算出定向光的贡献向量。最终将环境光、漫反射光和镜面反射光的贡献值整合为单一颜色向量返回。
2.6.2 点光源 Poing light
与方向光源类似,我们同样需要定义一个计算点光源对给定片段贡献值(含衰减)的函数。同样需要定义一个结构体来指定点光源所需的所有变量:
struct PointLight {
vec3 position;
float constant;
float linear;
float quadratic;
vec3 ambient;
vec3 diffuse;
vec3 specular;
};
#define NR_POINT_LIGHTS 4
uniform PointLight pointLights[NR_POINT_LIGHTS];
我们通过GLSL预处理指令定义场景中点光源数量。随后利用NR_POINT_LIGHTS常量创建PointLight结构体数组。GLSL中的数组与C#数组原理相同,可通过以下方式创建:
点光源函数的原型如下:
vec3 CalcPointLight(PointLight light, vec3 normal, vec3 fragPos, vec3 viewDir);
该函数将所需的所有数据作为参数传入,并返回一个vec3,该向量表示特定点光源对片段的颜色贡献。以下为该函数:
vec3 CalcPointLight(PointLight light, vec3 normal, vec3 fragPos, vec3 viewDir)
{
vec3 lightDir = normalize(light.position - fragPos);
// diffuse shading
float diff = max(dot(normal, lightDir), 0.0);
// specular shading
vec3 reflectDir = reflect(-lightDir, normal);
float spec = pow(max(dot(viewDir, reflectDir), 0.0), material.shininess);
// attenuation
float distance = length(light.position - fragPos);
float attenuation = 1.0 / (light.constant + light.linear * distance +
light.quadratic * (distance * distance));
// combine results
vec3 ambient = light.ambient * vec3(texture(material.diffuse, TexCoords));
vec3 diffuse = light.diffuse * diff * vec3(texture(material.diffuse, TexCoords));
vec3 specular = light.specular * spec * vec3(texture(material.specular, TexCoords));
ambient *= attenuation;
diffuse *= attenuation;
specular *= attenuation;
return (ambient + diffuse + specular);
}
将此功能封装为函数的优势在于,我们能够轻松计算多个点光源的照明效果,同时避免冗余代码的重复。在主函数中,只需创建一个循环遍历点光源数组,并为每个点光源调用CalcPointLight函数即可。
2.6.3 整合所有功能
现在我们分别定义了方向光源和点光源的计算函数,可以将其整合到主函数中。
void main()
{
// properties
vec3 norm = normalize(Normal);
vec3 viewDir = normalize(viewPos - FragPos);
// phase 1: Directional lighting
vec3 result = CalcDirLight(dirLight, norm, viewDir);
// phase 2: Point lights
for(int i = 0; i < NR_POINT_LIGHTS; i++)
result += CalcPointLight(pointLights[i], norm, FragPos, viewDir);
// phase 3: Spot light
//result += CalcSpotLight(spotLight, norm, FragPos, viewDir);
FragColor = vec4(result, 1.0);
}
每种光源依次贡献其光效至最终输出颜色,直至所有光源处理完毕。最终颜色包含场景中所有光源的综合光效。若需实现聚光灯效果,也可将其光效添加至输出颜色中。
方向光结构体的统一变量设置应该不会太陌生,但你可能会疑惑如何设置点光源的统一变量值---毕竟点光源的统一变量现在是一个PointLight结构体的数组。
设置结构体数组的统一变量与设置单个结构体并无二致,只是在查询统一变量位置时需额外指定索引:
lightingShader.setFloat("pointLights[0].constant", 1.0f);
在此我们索引pointLights数组中的首个PointLight结构体,并获取其常量变量的位置。遗憾的是这意味着我们必须手动为四个点光源分别设置所有统一变量,仅点光源部分就需要调用28次统一变量,操作略显繁琐。你可以尝试通过定义点光源类来抽象化处理,让该类自动设置统一变量,但最终仍需以这种方式为所有光源设置统一变量值。
还需要为每个点光源定义一个位置向量,因此让我们将它们在场景中分散开来。我们将定义另一个包含点光源位置的Vector3数组:
private readonly Vector3[] _pointLightPositions =
{
new Vector3(0.7f, 0.2f, 2.0f),
new Vector3(2.3f, -3.3f, -4.0f),
new Vector3(-4.0f, 2.0f, -12.0f),
new Vector3(0.0f, 0.0f, -3
658



被折叠的 条评论
为什么被折叠?



